Title
아두이노 예제
2017.02.07 23:16

WiFi Shield 101 Library - WiFi Web Server

조회 수 95 추천 수 0 댓글 0
?

단축키

Prev이전 문서

Next다음 문서

크게 작게 위로 아래로 댓글로 가기 인쇄 첨부
?

단축키

Prev이전 문서

Next다음 문서

크게 작게 위로 아래로 댓글로 가기 인쇄 첨부

이 예에서는 Wi-Fi실드 101과 Arduino 또는 Genuino Zero를 사용하여 간단한 웹 서버를 만들 수 있습니다. WiFi라이브러리를 사용하면 장치가 HTTP/1.1연결에서 수신된 HTTP요청에 응답할 수 있습니다. 브라우저를 열고 Wi-Fi의 IP주소를 탐색하거나 MKR1000의 IP주소를 입력하면 모든 6핀 핀에서 입력 값을 표시하기 위해 브라우저가 충분하게 HTML로 응답합니다.

 

이 예는 WPA암호화를 사용하여 네트워크를 위해 작성되었습니다. WEP또는 WPA의 경우, 그에 따라 Wifi.begin()호출을 변경한다.

 

Hardware Required


  • Arduino WiFi Shield 101
  • Arduino or Genuino Zero board

or

  • MKR1000
  • (optional) some sensors to attach to the analog inputs

 

Circuit


디지털 핀 7은 WiFi실드 101과 보드 사이의 핸드 핀으로 사용되며, 사용되지 않아야 합니다.

 

이예제를 위해 인터넷에 연결된 802.11b/g 무선 네트워크에 액세스 할 수 있는 권한이 있어야 합니다. 특정 네트워크 SSID와 일치하도록 스케치의 네트워크 설정을 변경해야 합니다.

 

WPA/WPA2 PersonalEncryption을 사용하는 네트워크에서는 SSID와 암호가 필요합니다. 이 실드는 WPA2엔터프라이즈 암호화를 사용하여 네트워크에 연결되지 않습니다.

 

WEP네트워크 암호는 키로 알려진 16진수 문자열입니다. WEP네트워크는 4개의 다른 키를 가질 수 있다. 각 키는 "키 인덱스"값을 할당합니다. WEP암호화된 네트워크의 경우 SSID, 키 및 키 번호가 필요합니다.

 

ArduinoWiFi101.png

 

상기 이미지에서 Arduino 또는 Genuino Zero보드는 WiFi실드 아래에 쌓여 있습니다.

 

Code


/*
  WiFi Web Server

 A simple web server that shows the value of the analog input pins.
 using a WiFi shield.

 This example is written for a network using WPA encryption. For
 WEP or WPA, change the WiFi.begin() call accordingly.

 Circuit:
 * WiFi shield attached
 * Analog inputs attached to pins A0 through A5 (optional)

 created 13 July 2010
 by dlf (Metodo2 srl)
 modified 31 May 2012
 by Tom Igoe

 */

#include <SPI.h>
#include <WiFi101.h>


char ssid[] = "yourNetwork";      // your network SSID (name)
char pass[] = "secretPassword";   // your network password
int keyIndex = 0;                 // your network key Index number (needed only for WEP)

int status = WL_IDLE_STATUS;

WiFiServer server(80);

void setup() {
  //Initialize serial and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }

  // check for the presence of the shield:
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi shield not present");
    // don't continue:
    while (true);
  }

  // attempt to connect to WiFi network:
  while ( status != WL_CONNECTED) {
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);
    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
    status = WiFi.begin(ssid, pass);

    // wait 10 seconds for connection:
    delay(10000);
  }
  server.begin();
  // you're connected now, so print out the status:
  printWiFiStatus();
}


void loop() {
  // listen for incoming clients
  WiFiClient client = server.available();
  if (client) {
    Serial.println("new client");
    // an http request ends with a blank line
    boolean currentLineIsBlank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        Serial.write(c);
        // if you've gotten to the end of the line (received a newline
        // character) and the line is blank, the http request has ended,
        // so you can send a reply
        if (c == '\n' && currentLineIsBlank) {
          // send a standard http response header
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connection: close");  // the connection will be closed after completion of the response
          client.println("Refresh: 5");  // refresh the page automatically every 5 sec
          client.println();
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");
          // output the value of each analog input pin
          for (int analogChannel = 0; analogChannel < 6; analogChannel++) {
            int sensorReading = analogRead(analogChannel);
            client.print("analog input ");
            client.print(analogChannel);
            client.print(" is ");
            client.print(sensorReading);
            client.println("<br />");
          }
          client.println("</html>");
          break;
        }
        if (c == '\n') {
          // you're starting a new line
          currentLineIsBlank = true;
        }
        else if (c != '\r') {
          // you've gotten a character on the current line
          currentLineIsBlank = false;
        }
      }
    }
    // give the web browser time to receive the data
    delay(1);

    // close the connection:
    client.stop();
    Serial.println("client disonnected");
  }
}


void printWiFiStatus() {
  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print your WiFi shield's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);

  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.print(rssi);
  Serial.println(" dBm");
}


List of Articles
번호 분류 제목 글쓴이 날짜 조회 수
311 아두이노 강좌 [아두이노 강좌] 03. RGB LED 색깔 변경하기 file 귀욤둥이 2017.02.21 219
310 아두이노 강좌 [아두이노 강좌] 02. LED 밝기 변경하기 file 귀욤둥이 2017.02.21 180
309 아두이노 강좌 [아두이노 강좌] 01. LED 깜빡이기 file 귀욤둥이 2017.02.20 153
308 아두이노 강좌 아두이노란 무엇 일까요??? file 귀욤둥이 2017.02.20 106
307 아두이노 예제 Wire Library - SFR Ranger Reader file 귀욤둥이 2017.02.08 139
306 아두이노 예제 Wire Library - Master Writer/Slave receiver file 귀욤둥이 2017.02.07 99
305 아두이노 예제 Wire Library - Master Reader/Slave Writer file 귀욤둥이 2017.02.07 88
304 아두이노 예제 Wire Library - Digital Potentiometer file 귀욤둥이 2017.02.07 115
303 아두이노 예제 WiFi Shield 101 Library - WiFi Send Receive UDP String file 귀욤둥이 2017.02.07 87
» 아두이노 예제 WiFi Shield 101 Library - WiFi Web Server file 귀욤둥이 2017.02.07 95
Board Pagination Prev 1 2 3 4 5 6 7 8 9 10 ... 33 Next
/ 33